The Short Answer

See below for where we get the $handle and $model variables.

  use Jifty::DBI::SchemaGenerator;
  ...
  my $s_gen = Jifty::DBI::SchemaGenerator->new( $handle );
  $s_gen->add_model($model);
  my @statements = $s_gen->create_table_sql_statements;
  print join("\n", @statements, '');
  ...

The Long Version

See Jifty::DBI for details about the first two parts.

MyModel

  package MyModel; 
  # lib/MyModel.pm
  use warnings;
  use strict;
  use base qw(Jifty::DBI::Record);
  # your custom code goes here.
  1;
    

MyModel::Schema

  package MyModel::Schema;
  # lib/MyModel/Schema.pm
  use warnings;
  use strict;
  use Jifty::DBI::Schema;
  column foo => type is 'text';
  column bar => type is 'text';
  1;
    

myscript.pl

  #!/usr/bin/env perl
  # myscript.pl
  use strict;
  use warnings;
  use Jifty::DBI::SchemaGenerator;
  use Jifty::DBI::Handle;
  use MyModel;
  use MyModel::Schema;
  my $handle = Jifty::DBI::Handle->new();
  $handle->connect(
    driver   => 'SQLite',
    database => 'testdb',
  );
  my $model = MyModel->new($handle);
  my $s_gen = Jifty::DBI::SchemaGenerator->new( $handle );
  $s_gen->add_model($model);
  # here's the basic point of this module:
  my @statements = $s_gen->create_table_sql_statements;
  print join("\n", @statements, '');
  # this part is directly from Jifty::Script::Schema::create_all_tables()
  $handle->begin_transaction;
  for my $statement (@statements) {
    my $ret = $handle->simple_query($statement);
    $ret or die "error creating a table: " . $ret->error_message;
  }
  $handle->commit;
    

new HANDLE

Creates a new "Jifty::DBI::SchemaGenerator" object. The single required argument is a "Jifty::DBI::Handle".

add_model MODEL

Adds a new model class to the SchemaGenerator. Model should be an object which is an instance of "Jifty::DBI::Record" or a subclass thereof. It may also be a string which is the name of such a class/subclass; in the latter case, "add_model" will instantiate an object of the class.

The model must define the instance methods "schema" and "table".

Returns true if the model was added successfully; returns a false "Class::ReturnValue" error otherwise.

column_definition_sql TABLENAME COLUMNNAME

Given a table name and a column name, returns the SQL fragment describing that column for the current database.

create_table_sql_statements

Returns a list of SQL statements (as strings) to create tables for all of the models added to the SchemaGenerator.

create_table_sql_text

Returns a string containing a sequence of SQL statements to create tables for all of the models added to the SchemaGenerator.

This is just a trivial wrapper around "create_table_sql_statements".

PRIVATE _db_schema_table_from_model MODEL

Takes an object of a subclass of Jifty::DBI::Record; returns a new "DBIx::DBSchema::Table" object corresponding to the model.

PRIVATE _error STRING

Takes in a string and returns it as a Class::ReturnValue error object.